//Kasutatakse faili aktsiad.dta
//Turu riskipreemia keskmise leidmine
quietly summarize mktrf
scalar mktrf_mean=r(mean)
//Riskivaba tulumäära keskmise leidmine
quietly summarize rf
scalar rf_mean=r(mean)
// Beetade leidmine
tempname betas
postfile `betas' beta_mktrf using "betas.dta", replace

foreach y of varlist eR* {
	regress `y' mktrf 
	scalar beta_mktrf=_b[mktrf]
	post `betas' (beta_mktrf)
}
postclose `betas'
// Tulumäärade keskmiste leidmine
tempname means
postfile `means' r_mean using "means.dta", replace
foreach var of varlist R* {
	quietly summarize `var'
	scalar r_mean=r(mean)
	post `means' (r_mean)
}
postclose `means'
// Beetad ja keskmised pannakse kokku vaatluse numbri järgi
clear
use "betas.dta"
merge 1:1 _n using "means.dta"
// SML joone regressioon
regress r_mean beta_mktrf
scalar lambda0=_b[_cons] 
scalar lambda1=_b[beta_mktrf]
//Tulemuste kuvamine
//SML joone võrrandi vabaliige
display lambda0
//Riskivaba tulumäära keskmine
display rf_mean
//SML joone võrrandi tõus
display lambda1
//Turu tulumäära keskmine
display mktrf_mean
//Testitakse, kas SML joone võrrandis
//võib  sirge tõus võrduda turu tulumäära keskmisega
//Kasutatakse kitsenduste F-testi
test (_b[beta_mktrf]=mktrf_mean)
//SML joone diagramm
avplots